trend

- 4

Trapped Radiation ENvironment model Development

Frequently Asked Questions

[ Question | Answer | Illustration | See Also ]

Question

    T.04 - Why are Roederer's L* and McIlwain's L parameters different ?

Answer

    In a magnetic dipole field, the parameter L is defined as the distance from the center of the dipole to the equatorial point (or minimum B value) of the field line. The parameter L is given in units of Earth's radii and, in a dipole field, a particle remains during its bounce and drift motion on magnetic field lines having the same L.

    For a non-dipolar geomagnetic field, e.g. IGRF, coordinate systems based on adiabatic invariants are used. To provide a familiar and easy-to-interpret variable, Roederer and McIlwain have related adiabatic invariants to the parameter L: McIlwain's parameter (Lm) is a function of the magnetic field intensity Bm at the mirror point, the integral invariant function I and the magnetic moment M of the dipole field while Roederer's parameter L* is a function of the third adiabatic invariant and the magnetic moment M. When the magnetic field model is fixed and frozen, a particle has constant Lm and constant L* values during its bounce and drift motion. Generally, both values of L are different, except in the case of a dipole magnetic field model where both values should be the same.

    In the UNILIB libray, for historical reasons, the dipole magnetic moment used to evaluate the parameters Lm and L* is not equal to the magnetic moment of the magnetic field but is fixed to M0 = 0.311653 Gauss Re-3 (see common block UC160, argument gmagmo). Due to this feature, the two parameters are different even with a magnetic dipole. The argument kmflg of the common block UC190 allows to control the evaluation of the L parameters in the subroutines UL240, UL242 and UD330. When the variable kmflg is set to 0 or 10, the magnetic moment M0 is used, while when the variable is set to 1 or 11, the magnetic moment of the magnetic field is used. Note that this last moment is stored in the common block UC140 (argument mint.gmmo).

References

  • McIlwain, C.E., Coordinates for mapping the distribution of magnetically trapped particles, JGR 66 (1961) 3681-3691
  • Roederer, J.G., Dynamics of geomagnetically trapped radiation, 1970, Springer-Verlag, New York

Illustration

    The use of the variable kmflg is illustrated with a sample program based on example #3 (evaluation of the third invariant). In this example, a magnetic dipole field is selected and a drift shell is defined with the help of the (Bm,Lm) parameter values: Bm = 0.19 Gauss and Lm = 2.00. The Roederer's L* parameter is then evaluated successively with the magnetic moment M0 and with the true magnetic field moment. The results are 2.06 and 2.01, respectively. The difference of 0.5% between the last result and Lm provides a measure of the error in the evaluation of the third invariant by the subroutine UD330.

Source

      PROGRAM faqt04
C             (based on example3)
C
      INCLUDE 'structure.h'
C
      COMMON /UC190/ prop, stepx, stpmin, umsq, upsq, uk2, uk3, 
     :               epskm, epsrel, stplst, xclat, kmflg, nxstp       
C
      REAL*8       prop, stepx, stpmin
      REAL*8       umsq, upsq, uk2, uk3
      REAL*8       epskm, epsrel, stplst, xclat
      INTEGER*4    kmflg, nxstp      
C
      INTEGER*4    kunit, kinit, ifail, kint, kext, noprint
      CHARACTER*32 lbint, lbext
      REAL*8       year, param(10), amjd
      INTEGER*4    knfl, ktyplus
      REAL*8       fbm0, flm0, falt, phi, star0, star1
C
C     initialize variables
C
      DATA kunit, kinit, noprint/ 6, 1, -6/
      DATA kint, kext/ 3, 0/
      DATA year, amjd, param/ 1995.0d0, 0.0d0, 10*0.0d0/
C
C     initialize the library and the magnetic dipole field
C
      CALL UT990 (noprint, kinit, ifail)
      IF( ifail .LT. 0 )STOP
      CALL UM510 (kint, year, lbint, kunit, ifail)
      IF( ifail .LT. 0 )STOP
      CALL UM520 (kext, amjd, param,
     :           lbext, noprint, ifail)
      IF( ifail .LT. 0 )STOP
C
C     trace the drift shell and evaluate the third invariant
C     in the STANDARD case
C
      fbm0          =    0.19d0
      flm0          =    2.0d0
      falt          =    0.0d0
      knfl          =  120
      ktyplus       =    3
C
      CALL UD310 (fbm0, flm0, falt, knfl, 
     :           ktyplus, ifail)
          IF( ifail .LT. 0 )STOP
      CALL UD330 (phi, star0, ifail) 
          IF( ifail .LT. 0 )STOP
C
C     trace the drift shell and evaluate the third invariant
C     when KMFLG is set to one
C
      kmflg         =    1
C
      CALL UD310 (fbm0, flm0, falt, knfl, 
     :           ktyplus, ifail)
          IF( ifail .LT. 0 )STOP
      CALL UD330 (phi, star1, ifail) 
          IF( ifail .LT. 0 )STOP
C
C     write the result
C
      WRITE(*,*) star0, star1
C
      END

Results


--- Geomagnetic field model ---

     Model ( 3): Dipolar magnetic field             Epoch 1995.
                            Order + 1 =    2
                    Calculation epoch = 1995.0      year
        Colatitude of the dipole pole =   10.70     deg
         Longitude of the dipole pole =  -71.41     deg
                  Earth dipole moment =    0.302077 G/Re^3
         Correction for the SAA drift =    0.00     deg
  2.06304946287526        2.01249780345246

See also

    None